home *** CD-ROM | disk | FTP | other *** search
/ Linear Technology Linearview 1996 / linearview 1996.iso / spice / demoriaa.cir < prev    next >
Encoding:
Text File  |  1996-07-09  |  4.3 KB  |  135 lines
  1. LTC LT1115 RIAA audio circuit demo (Out=V(58))
  2. *
  3. *                          Walt Jung
  4. *            RIAA moving magnet phono preamp (40dB gain)
  5. *                           1/02/90
  6. *
  7. * This preamp circuit is an example which uses a number of PSpice
  8. * features to advantage while demonstrating the performance of the
  9. * LT1115 op amp for audio.  The circuit below is shown on page one of
  10. * the device data sheet.  SPICE simulation was used in the initial
  11. * development of this circuit, and it served also as a test case
  12. * for the LT1115 model itself.  As noted on the data sheet, there
  13. * is good agreement between the simulated frequency response and that
  14. * actually measured on the real circuit.
  15. *
  16. * In this demo, the Probe CMD file supplied calls up display parameters
  17. * which show the (equalized) RIAA response with a scale of 10Hz-100kHz,
  18. * with a +/- 0.5dB window.  You can easily modify these, to suit yourself.
  19. * Further comments are contained below (as ";").
  20. *
  21. .OPT ACCT LIST NODE OPTS NOPAGE RELTOL=0.0001
  22. .WIDTH OUT=80 
  23. .TEMP 27 
  24. .AC DEC 10 10 100KHZ
  25. VIN 1 0 AC 0.1
  26. .PROBE 
  27. .OP
  28. .INC RIAAREF.INC        ; inverse RIAA pre-emph. network, -40dB @ 1kHz
  29. *                       ; (ala Jung/Lipshitz; see ".INC" file)
  30. VCC   52    0  +18V
  31. VEE   53    0  -18V
  32. Rin   3    50  10
  33. R1    57   100 210k
  34. R2    100  101 17.8k
  35. Rz    101  51  499
  36. Ra1   51   102 22.6     ; tweak these two for gain adj., (if desired)
  37. Ra2   102  103 210      ;
  38. Rx    57   58  562
  39. Ry    58   0   25k      ; simulated load of next stage
  40. Rd    57   103 82.5k
  41. C1    57   100 15000pF
  42. C2a   100  101 3900pF
  43. C2b   100  101 330pF
  44. Cba   103  0   2200uF
  45. Cbb   103  0   4.7uF
  46. Cc    58   0   3900pF
  47. E1010 57 0 56 0  1
  48. C4    56   0   1pf
  49. R5    55   56  100
  50. *     (+) (-)  V+  V-  OUT
  51. XU1    50  51  52  53  55  LT1115
  52. .SUBCKT LT1115 3 2 7 4 6
  53. RC1 7 80 7.0736E+01 
  54. RC2 7 90 7.0736E+01 
  55. Q1 80 2 10 QM1 
  56. Q2 90 3 11 QM2 
  57. C1 80 91 750E-12 
  58. RXC1 91 90 50 
  59. CXC1 91 90 400E-12 
  60. C2 1 98 30.000E-12 
  61. RXC2 98 8 1K 
  62. CXC2 98 8 10.000E-12 
  63. CIN 2 3 15E-12 
  64. RIN 2 3 2E4 
  65. DDM1 2 104 DM2
  66. DDM3 104 3 DM2
  67. DDM2 3 105 DM2
  68. DDM4 105 2 DM2
  69. RE1 10 12 -4.4157E+01 
  70. RE2 11 12 -4.4157E+01 
  71. IEE 12 4 4.5006E-04
  72. RE 12 0 4.4439E+05
  73. CE 12 0 1.5789E-12
  74. GCM 0 8 12 0 7.0854E-09
  75. GA 8 0 80 90 1.4137E-02 
  76. R2 8 0 1.0000E+05
  77. GB 1 0 8 0 2.6731E+02 
  78. RO2 1 0 7.9000E+01
  79. RS 1 6 1 
  80. ECL 18 0 1 6 2.7910E+01
  81. GCL 0 8 20 0 1
  82. RCL 20 0 1E3
  83. D1 18 20 DM1 
  84. D2 20 18 DM1 
  85. D3A 131 70 DM3 
  86. D3B 13 131 DM3 
  87. GPL 0 8 70 7 1 
  88. VC 13 6 3.6394
  89. RPLA 7 70 1E4 
  90. RPLB 7 131 1E5 
  91. D4A 60 141 DM3
  92. D4B 141 14 DM3
  93. GNL 0 8 60 4 1 
  94. VE 6 14 3.6394
  95. RNLA 60 4 1E4 
  96. RNLB 141 4 1E5 
  97. IP 7 4 7.450E-03
  98. DSUB 4 7 DM2 
  99. .MODEL QM1 NPN (IS=8.0000E-16 BF=3.4615E+03)
  100. .MODEL QM2 NPN (IS=8.0155E-16 BF=6.4286E+03)
  101. .MODEL DM1 D (IS=1.000E-19)
  102. .MODEL DM2 D (IS=8.000E-16)
  103. .MODEL DM3 D (IS=1.000E-20)
  104. .ENDS LT1115
  105. **
  106. *         (C) COPYRIGHT LINEAR TECHNOLOGY CORPORATION 1990
  107. *                       All rights reserved.
  108. * 
  109. *   Linear Technology Corporation hereby grants the users of this
  110. * macromodel a non-exclusive, nontransferrable license to use this
  111. *            macromodel under the following conditions:
  112. * 
  113. * The user agrees that this macromodel is licensed from Linear
  114. * Technology and agrees that the macromodel may be used, loaned,
  115. * given away or included in other model libraries as long as this
  116. * notice and the model in its entirety and unchanged is included.
  117. * No right to make derivative works or modifications to the
  118. * macromodel is granted hereby.  All such rights are reserved.
  119. * 
  120. * This model is provided as is.  Linear Technology makes no
  121. * warranty, either expressed or implied about the suitability or
  122. * fitness of this model for any particular purpose.  In no event
  123. * will Linear Technology be liable for special, collateral,
  124. * incidental or consequential damages in connection with or arising
  125. * out of the use of this macromodel.  It should be remembered that
  126. * models are a simplification of the actual circuit.
  127. * 
  128. * Linear Technology reserves the right to change these macromodels
  129. * without prior notice.  Contact Linear Technology at 1630 McCarthy
  130. * Blvd., Milpitas, CA, 95035-7487 or telephone 408/432-1900 for
  131. * datasheets on the actual amplifiers or the latest macromodels.
  132. * 
  133. * ----------------------------------------------------------------------- *
  134. .END
  135.